SMESH_MeshEditor.idl

Go to the documentation of this file.

// Copyright (C) 2007-2026  CEA, EDF, OPEN CASCADE
//
// Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
// CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
//
// This library is free software; you can redistribute it and/or
// modify it under the terms of the GNU Lesser General Public
// License as published by the Free Software Foundation; either
// version 2.1 of the License, or (at your option) any later version.
//
// This library is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
// Lesser General Public License for more details.
//
// You should have received a copy of the GNU Lesser General Public
// License along with this library; if not, write to the Free Software
// Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
//
// See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
//
//  File   : SMESH_MeshEditor.idl
 
#ifndef _SMESH_MESHEDITOR_IDL_
#define _SMESH_MESHEDITOR_IDL_
 
#include "SMESH_Mesh.idl"
#include "SMESH_Gen.idl"
#include "SMESH_smIdType.idl"
 
module SMESH
{
  interface NumericalFunctor;
 
  enum Bnd_Dimension { BND_2DFROM3D, BND_1DFROM3D, BND_1DFROM2D };
 
 
  struct FreeBorder
  {
    SMESH::smIdType_array nodeIDs; // all nodes defining a free border
    // 1st and last node is same in a closed border
  };
  struct FreeBorderPart
  {
    short border; // border index within a sequence<FreeBorder>
    long  node1;  // node index within the border-th FreeBorder
    long  node2;
    long  nodeLast;
  };
  typedef sequence<FreeBorder>       ListOfFreeBorders;
  typedef sequence<FreeBorderPart>   FreeBordersGroup;
  typedef sequence<FreeBordersGroup> ListOfFreeBorderGroups;
 
  struct CoincidentFreeBorders
  {
    ListOfFreeBorders      borders;          // nodes of all free borders
    ListOfFreeBorderGroups coincidentGroups; // groups of coincident parts of borders
  };
 
 
  // structure used in MakePolyLine() to define a cutting plane
  struct PolySegment
  {
    // a point is defined as follows:
    // ( node*ID1 > 0 && node*ID2 > 0 ) ==> point is in the middle of an edge defined by two nodes
    // ( node*ID1 > 0 && node*ID2 <=0 ) ==> point is at node*ID1
    // else                             ==> point is at xyz*
 
    // point 1
    smIdType node1ID1;
    smIdType node1ID2;
    PointStruct xyz1;
 
    // point 2
    smIdType node2ID1;
    smIdType node2ID2;
    PointStruct xyz2;
 
    // vector on the plane; to use a default plane set vector = (0,0,0)
    DirStruct vector;
  };
  typedef sequence<PolySegment> ListOfPolySegments;
 
  // face edge defined by two nodes + optional medium node
  struct FaceEdge
  {
    smIdType node1;
    smIdType node2;
    smIdType medium;
  };
  typedef sequence<FaceEdge> ListOfEdges;
 
 
  interface SMESH_MeshEditor
  {
    SMESH_Mesh GetMesh();
 
    MeshPreviewStruct GetPreviewData() raises (SALOME::SALOME_Exception);
 
    smIdType_array GetLastCreatedNodes() raises (SALOME::SALOME_Exception);
 
    smIdType_array GetLastCreatedElems() raises (SALOME::SALOME_Exception);
 
    void ClearLastCreated() raises (SALOME::SALOME_Exception);
 
    ComputeError GetLastError() raises (SALOME::SALOME_Exception);
 
    SMESH_IDSource MakeIDSource(in smIdType_array IDsOfElements, in ElementType type);
 
    boolean RemoveElements(in smIdType_array IDsOfElements) raises (SALOME::SALOME_Exception);
 
    boolean RemoveNodes(in smIdType_array IDsOfNodes) raises (SALOME::SALOME_Exception);
 
    smIdType RemoveOrphanNodes() raises (SALOME::SALOME_Exception);
 
    void RemoveNodeWithReconnection(in smIdType nodeID) raises (SALOME::SALOME_Exception);
 
    smIdType AddNode(in double x, in double y, in double z) raises (SALOME::SALOME_Exception);
 
    smIdType Add0DElement(in smIdType    IDOfNode,
                          in boolean DuplicateElements) raises (SALOME::SALOME_Exception);
 
    smIdType AddBall(in smIdType IDOfNode, in double diameter) raises (SALOME::SALOME_Exception);
 
    smIdType AddEdge(in smIdType_array IDsOfNodes) raises (SALOME::SALOME_Exception);
 
    smIdType AddFace(in smIdType_array IDsOfNodes) raises (SALOME::SALOME_Exception);
 
    smIdType AddPolygonalFace(in smIdType_array IdsOfNodes) raises (SALOME::SALOME_Exception);
 
    smIdType AddQuadPolygonalFace(in smIdType_array IdsOfNodes) raises (SALOME::SALOME_Exception);
 
    smIdType AddVolume(in smIdType_array IDsOfNodes) raises (SALOME::SALOME_Exception);
 
    smIdType AddPolyhedralVolume (in smIdType_array IdsOfNodes,
                                  in long_array Quantities) raises (SALOME::SALOME_Exception);
    smIdType AddPolyhedralVolumeByFaces (in smIdType_array IdsOfFaces) raises (SALOME::SALOME_Exception);
 
    SMESH_IDSource Create0DElementsOnAllNodes(in SMESH_IDSource theObject,
                                              in string         theGroupName,
                                              in boolean        theDuplicateElements)
      raises (SALOME::SALOME_Exception);
 
    void SetNodeOnVertex(in smIdType NodeID, in long VertexID)
      raises (SALOME::SALOME_Exception);
    void SetNodeOnEdge(in smIdType NodeID, in long EdgeID, in double paramOnEdge)
      raises (SALOME::SALOME_Exception);
    void SetNodeOnFace(in smIdType NodeID, in long FaceID, in double u, in double v)
      raises (SALOME::SALOME_Exception);
    void SetNodeInVolume(in smIdType NodeID, in long SolidID)
      raises (SALOME::SALOME_Exception);
    void SetMeshElementOnShape(in smIdType ElementID, in long ShapeID)
      raises (SALOME::SALOME_Exception);
 
 
    boolean MoveNode(in smIdType NodeID, in double x, in double y, in double z)
      raises (SALOME::SALOME_Exception);
 
    boolean InverseDiag(in smIdType NodeID1, in smIdType NodeID2) 
      raises (SALOME::SALOME_Exception);
    boolean DeleteDiag(in smIdType NodeID1, in smIdType NodeID2) 
      raises (SALOME::SALOME_Exception);
    void AddNodeOnSegment(in smIdType Node1, in smIdType Node2, in double position)
      raises (SALOME::SALOME_Exception);
    void AddNodeOnFace(in smIdType triangle, in double x, in double y, in double z);
 
    boolean Reorient(in smIdType_array IDsOfElements) 
      raises (SALOME::SALOME_Exception);
    boolean ReorientObject(in SMESH_IDSource theObject) 
      raises (SALOME::SALOME_Exception);
    long Reorient2D(in SMESH_IDSource the2Dgroup,
                    in DirStruct      theDirection,
                    in long           theFace,
                    in PointStruct    thePoint) raises (SALOME::SALOME_Exception);
    long Reorient2DByNeighbours(in SMESH::ListOfIDSources objectFaces,
                                in SMESH::ListOfIDSources referenceFaces)
      raises (SALOME::SALOME_Exception);
 
    long Reorient2DBy3D(in ListOfIDSources faces,
                        in SMESH_IDSource  volumes,
                        in boolean         outsideNormal) raises (SALOME::SALOME_Exception);
 
    boolean TriToQuad (in smIdType_array   IDsOfElements,
                       in NumericalFunctor Criterion,
                       in double           MaxAngle) raises (SALOME::SALOME_Exception);
    boolean TriToQuadObject (in SMESH_IDSource   theObject,
                             in NumericalFunctor Criterion,
                             in double           MaxAngle) raises (SALOME::SALOME_Exception);
 
    boolean QuadToTri (in smIdType_array   IDsOfElements,
                       in NumericalFunctor Criterion) raises (SALOME::SALOME_Exception);
    boolean QuadToTriObject (in SMESH_IDSource   theObject,
                             in NumericalFunctor Criterion) raises (SALOME::SALOME_Exception);
    void QuadTo4Tri (in SMESH_IDSource theQuads) raises (SALOME::SALOME_Exception);
 
    boolean SplitQuad (in smIdType_array IDsOfElements,
                       in boolean        Diag13) raises (SALOME::SALOME_Exception);
    boolean SplitQuadObject (in SMESH_IDSource theObject,
                             in boolean        Diag13) raises (SALOME::SALOME_Exception);
 
    short BestSplit (in smIdType         IDOfQuad,
                     in NumericalFunctor Criterion) raises (SALOME::SALOME_Exception);
 
    void SplitVolumesIntoTetra(in SMESH_IDSource elems, in short methodFlags)
      raises (SALOME::SALOME_Exception);
 
    void SplitVolumesIntoTetraAvoidOverConstrainedVolumes(in SMESH_IDSource elems, in short methodFlags)
      raises (SALOME::SALOME_Exception);
 
    void SplitHexahedraIntoPrisms(in SMESH_IDSource     elems,
                                  in SMESH::PointStruct startHexPoint,
                                  in SMESH::DirStruct   facetToSplitNormal,
                                  in short              methodFlags,
                                  in boolean            allDomains)
      raises (SALOME::SALOME_Exception);
 
    void SplitBiQuadraticIntoLinear(in ListOfIDSources elems)
      raises (SALOME::SALOME_Exception);
 
 
    enum Smooth_Method { LAPLACIAN_SMOOTH, CENTROIDAL_SMOOTH };
 
    boolean Smooth(in smIdType_array IDsOfElements,
                   in smIdType_array IDsOfFixedNodes,
                   in short          MaxNbOfIterations,
                   in double         MaxAspectRatio,
                   in Smooth_Method  Method) raises (SALOME::SALOME_Exception);
 
    boolean SmoothObject(in SMESH_IDSource theObject,
                         in smIdType_array IDsOfFixedNodes,
                         in short          MaxNbOfIterations,
                         in double         MaxAspectRatio,
                         in Smooth_Method  Method) raises (SALOME::SALOME_Exception);
 
    boolean SmoothParametric(in smIdType_array IDsOfElements,
                             in smIdType_array IDsOfFixedNodes,
                             in short          MaxNbOfIterations,
                             in double         MaxAspectRatio,
                             in Smooth_Method  Method) raises (SALOME::SALOME_Exception);
 
    boolean SmoothParametricObject(in SMESH_IDSource theObject,
                                   in smIdType_array IDsOfFixedNodes,
                                   in short          MaxNbOfIterations,
                                   in double         MaxAspectRatio,
                                   in Smooth_Method  Method) raises (SALOME::SALOME_Exception);
 
    void ConvertToQuadratic(in boolean theForce3d) 
      raises (SALOME::SALOME_Exception);
    void ConvertToQuadraticObject(in boolean        theForce3d, 
                                  in SMESH_IDSource theObject) 
      raises (SALOME::SALOME_Exception);
    
    boolean ConvertFromQuadratic() 
      raises (SALOME::SALOME_Exception);
    void    ConvertFromQuadraticObject(in SMESH_IDSource theObject)
      raises (SALOME::SALOME_Exception);
 
    void ConvertToBiQuadratic(in boolean        theForce3d,
                              in SMESH_IDSource theObject)
      raises (SALOME::SALOME_Exception);
 
    void RenumberNodes() raises (SALOME::SALOME_Exception);
 
    void RenumberElements() raises (SALOME::SALOME_Exception);
 
    ListOfGroups RotationSweepObjects(in ListOfIDSources Nodes,
                                      in ListOfIDSources Edges,
                                      in ListOfIDSources Faces,
                                      in AxisStruct      Axis,
                                      in double          AngleInRadians,
                                      in long            NbOfSteps,
                                      in double          Tolerance,
                                      in boolean         ToMakeGroups)
      raises (SALOME::SALOME_Exception);
 
    ListOfGroups ExtrusionSweepObjects(in ListOfIDSources nodes,
                                       in ListOfIDSources edges,
                                       in ListOfIDSources faces,
                                       in DirStruct       stepVector,
                                       in long            nbOfSteps,
                                       in boolean         toMakeGroups,
                                       in double_array    scaleFactors,
                                       in boolean         scaleVariation,
                                       in double_array    basePoint,
                                       in double_array    angles,
                                       in boolean         angleVariation)
      raises (SALOME::SALOME_Exception);
 
    ListOfGroups ExtrusionByNormal(in ListOfIDSources theObjects,
                                   in double          stepSize,
                                   in long            nbOfSteps,
                                   in boolean         byAverageNormal,
                                   in boolean         useInputElemsOnly,
                                   in boolean         makeGroups,
                                   in short           dim)
      raises (SALOME::SALOME_Exception);
 
    ListOfGroups AdvancedExtrusion(in smIdType_array IDsOfElements,
                                   in DirStruct      StepVector,
                                   in long           NbOfSteps,
                                   in long           ExtrFlags,
                                   in double         SewTolerance,
                                   in boolean        ToMakeGroups)
      raises (SALOME::SALOME_Exception);
 
    enum Extrusion_Error {
      EXTR_OK,
      EXTR_NO_ELEMENTS,
      EXTR_PATH_NOT_EDGE,
      EXTR_BAD_PATH_SHAPE,
      EXTR_BAD_STARTING_NODE,
      EXTR_BAD_ANGLES_NUMBER,
      EXTR_CANT_GET_TANGENT
    };
 
    ListOfGroups ExtrusionAlongPathObjects(in ListOfIDSources   Nodes,
                                           in ListOfIDSources   Edges,
                                           in ListOfIDSources   Faces,
                                           in SMESH_IDSource    Path,
                                           in GEOM::GEOM_Object PathShape,
                                           in smIdType          NodeStart,
                                           in boolean           HasAngles,
                                           in double_array      Angles,
                                           in boolean           AnglesVariation,
                                           in boolean           HasRefPoint,
                                           in PointStruct       RefPoint,
                                           in boolean           MakeGroups,
                                           in double_array      ScaleFactors,
                                           in boolean           ScaleVariation,
                                           out Extrusion_Error  Error)
      raises (SALOME::SALOME_Exception);
 
    double_array LinearAnglesVariation(in SMESH_Mesh        PathMesh,
                                       in GEOM::GEOM_Object PathShape,
                                       in double_array      Angles);
 
    enum MirrorType { POINT, AXIS, PLANE };
 
    void Mirror (in smIdType_array IDsOfElements,
                 in AxisStruct     Mirror,
                 in MirrorType     Type,
                 in boolean        Copy) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups MirrorMakeGroups (in smIdType_array IDsOfElements,
                                   in AxisStruct     Mirror,
                                   in MirrorType     Type) 
      raises (SALOME::SALOME_Exception);
    SMESH_Mesh MirrorMakeMesh (in smIdType_array IDsOfElements,
                               in AxisStruct     Mirror,
                               in MirrorType     Type,
                               in boolean        CopyGroups,
                               in string         MeshName) 
      raises (SALOME::SALOME_Exception);
 
    void MirrorObject (in SMESH_IDSource theObject,
                       in AxisStruct     Mirror,
                       in MirrorType     Type,
                       in boolean        Copy) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups MirrorObjectMakeGroups (in SMESH_IDSource theObject,
                                         in AxisStruct     Mirror,
                                         in MirrorType     Type) 
      raises (SALOME::SALOME_Exception);
    SMESH_Mesh MirrorObjectMakeMesh (in SMESH_IDSource theObject,
                                     in AxisStruct     Mirror,
                                     in MirrorType     Type,
                                     in boolean        CopyGroups,
                                     in string         MeshName) 
      raises (SALOME::SALOME_Exception);
 
    void Translate (in smIdType_array IDsOfElements,
                    in DirStruct      Vector,
                    in boolean        Copy) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups TranslateMakeGroups (in smIdType_array IDsOfElements,
                                      in DirStruct       Vector) 
      raises (SALOME::SALOME_Exception);
    SMESH_Mesh TranslateMakeMesh (in smIdType_array IDsOfElements,
                                  in DirStruct      Vector,
                                  in boolean        CopyGroups,
                                  in string         MeshName) 
      raises (SALOME::SALOME_Exception);
 
    void TranslateObject (in SMESH_IDSource theObject,
                          in DirStruct      Vector,
                          in boolean        Copy) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups TranslateObjectMakeGroups (in SMESH_IDSource theObject,
                                            in DirStruct      Vector) 
      raises (SALOME::SALOME_Exception);
    SMESH_Mesh TranslateObjectMakeMesh (in SMESH_IDSource theObject,
                                        in DirStruct      Vector,
                                        in boolean        CopyGroups,
                                        in string         MeshName) 
      raises (SALOME::SALOME_Exception);
 
    void Scale (in SMESH_IDSource theObject,
                in PointStruct    thePoint,
                in double_array   theScaleFact,
                in boolean        Copy) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups ScaleMakeGroups (in SMESH_IDSource theObject,
                                  in PointStruct    thePoint,
                                  in double_array   theScaleFact) 
      raises (SALOME::SALOME_Exception);
    SMESH_Mesh ScaleMakeMesh (in SMESH_IDSource theObject,
                              in PointStruct    thePoint,
                              in double_array   theScaleFact,
                              in boolean        CopyGroups,
                              in string         MeshName) 
      raises (SALOME::SALOME_Exception);
 
    void Rotate (in smIdType_array IDsOfElements,
                 in AxisStruct     Axis,
                 in double         AngleInRadians,
                 in boolean        Copy) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups RotateMakeGroups (in smIdType_array IDsOfElements,
                                   in AxisStruct     Axis,
                                   in double         AngleInRadians) 
      raises (SALOME::SALOME_Exception);
    SMESH_Mesh RotateMakeMesh (in smIdType_array IDsOfElements,
                               in AxisStruct     Axis,
                               in double         AngleInRadians,
                               in boolean        CopyGroups,
                               in string         MeshName)
      raises (SALOME::SALOME_Exception);
 
    void RotateObject (in SMESH_IDSource theObject,
                       in AxisStruct     Axis,
                       in double         AngleInRadians,
                       in boolean        Copy)
      raises (SALOME::SALOME_Exception);
    ListOfGroups RotateObjectMakeGroups (in SMESH_IDSource theObject,
                                         in AxisStruct     Axis,
                                         in double         AngleInRadians)
      raises (SALOME::SALOME_Exception);
    SMESH_Mesh RotateObjectMakeMesh (in SMESH_IDSource theObject,
                                     in AxisStruct     Axis,
                                     in double         AngleInRadians,
                                     in boolean        CopyGroups,
                                     in string         MeshName)
      raises (SALOME::SALOME_Exception);
 
    SMESH_Mesh Offset(in SMESH_IDSource theObject,
                      in double         Value,
                      in boolean        CopyGroups,
                      in boolean        CopyElements,
                      in string         MeshName,
                      out ListOfGroups  Groups)
      raises (SALOME::SALOME_Exception);
 
    void FindCoincidentNodes (in  double              Tolerance,
                              out array_of_long_array GroupsOfNodes,
                              in  boolean             SeparateCornersAndMedium)
      raises (SALOME::SALOME_Exception);
 
    void FindCoincidentNodesOnPart (in  SMESH_IDSource      SubMeshOrGroup,
                                    in  double              Tolerance,
                                    out array_of_long_array GroupsOfNodes,
                                    in  boolean             SeparateCornersAndMedium)
      raises (SALOME::SALOME_Exception);
 
    void FindCoincidentNodesOnPartBut (in  ListOfIDSources     SubMeshOrGroup,
                                       in  double              Tolerance,
                                       out array_of_long_array GroupsOfNodes,
                                       in  ListOfIDSources     ExceptSubMeshOrGroups,
                                       in  boolean             SeparateCornersAndMedium)
      raises (SALOME::SALOME_Exception);
 
    void MergeNodes (in array_of_long_array    GroupsOfNodes,
                     in SMESH::ListOfIDSources NodesToKeep,
                     in boolean                AvoidMakingHoles)
      raises (SALOME::SALOME_Exception);
 
    void FindEqualElements (in  ListOfIDSources     MeshOrSubMeshOrGroup,
                            in  ListOfIDSources     ExceptSubMeshOrGroups,
                            out array_of_long_array GroupsOfElementsID) 
      raises (SALOME::SALOME_Exception);
 
    void MergeElements(in array_of_long_array    GroupsOfElementsID,
                       in SMESH::ListOfIDSources ElementsToKeep) 
      raises (SALOME::SALOME_Exception);
 
    void MergeEqualElements() 
      raises (SALOME::SALOME_Exception);
 
    smIdType MoveClosestNodeToPoint(in double x, in double y, in double z, in smIdType nodeID) 
      raises (SALOME::SALOME_Exception);
 
    smIdType FindNodeClosestTo(in double x, in double y, in double z) 
      raises (SALOME::SALOME_Exception);
 
    smIdType_array FindElementsByPoint(in double x, in double y, in double z, in ElementType type) 
      raises (SALOME::SALOME_Exception);
 
    smIdType_array FindAmongElementsByPoint(in SMESH_IDSource elements,
                                            in double x, in double y, in double z,
                                            in ElementType type)
      raises (SALOME::SALOME_Exception);
 
    smIdType ProjectPoint(in double         x,
                          in double         y,
                          in double         z,
                          in ElementType    type,
                          in SMESH_IDSource meshObject,
                          out double_array  projecton)
      raises (SALOME::SALOME_Exception);
 
    short GetPointState(in double x, in double y, in double z)
      raises (SALOME::SALOME_Exception);
 
    boolean IsManifold()
      raises (SALOME::SALOME_Exception);
 
    boolean IsCoherentOrientation2D()
      raises (SALOME::SALOME_Exception);
 
    array_of_long_array Get1DBranches( in SMESH_IDSource       edges,
                                       in smIdType             startNode,
                                       out array_of_long_array nodeGroups)
      raises (SALOME::SALOME_Exception);
 
    ListOfEdges FindSharpEdges(in double angle, in boolean addExistingEdges)
      raises (SALOME::SALOME_Exception);
 
    ListOfFreeBorders FindFreeBorders(in boolean closedOnly)
      raises (SALOME::SALOME_Exception);
 
    SMESH_Group FillHole(in FreeBorder hole, in string groupName)
      raises (SALOME::SALOME_Exception);
 
    CoincidentFreeBorders FindCoincidentFreeBorders(in double tolerance);
 
    short SewCoincidentFreeBorders (in CoincidentFreeBorders freeBorders,
                                    in boolean               createPolygons,
                                    in boolean               createPolyedrs)
      raises (SALOME::SALOME_Exception);
 
    enum Sew_Error {
      SEW_OK,
      SEW_BORDER1_NOT_FOUND,
      SEW_BORDER2_NOT_FOUND,
      SEW_BOTH_BORDERS_NOT_FOUND,
      SEW_BAD_SIDE_NODES,
      SEW_VOLUMES_TO_SPLIT,
      // for SewSideElements() only:
      SEW_DIFF_NB_OF_ELEMENTS,
      SEW_TOPO_DIFF_SETS_OF_ELEMENTS,
      SEW_BAD_SIDE1_NODES,
      SEW_BAD_SIDE2_NODES,
      SEW_INTERNAL_ERROR
    };
 
    Sew_Error SewFreeBorders (in smIdType FirstNodeID1,
                              in smIdType SecondNodeID1,
                              in smIdType LastNodeID1,
                              in smIdType FirstNodeID2,
                              in smIdType SecondNodeID2,
                              in smIdType LastNodeID2,
                              in boolean  CreatePolygons,
                              in boolean  CreatePolyedrs) 
      raises (SALOME::SALOME_Exception);
 
    Sew_Error SewConformFreeBorders (in smIdType FirstNodeID1,
                                     in smIdType SecondNodeID1,
                                     in smIdType LastNodeID1,
                                     in smIdType FirstNodeID2,
                                     in smIdType SecondNodeID2) 
      raises (SALOME::SALOME_Exception);
 
    Sew_Error SewBorderToSide (in smIdType FirstNodeIDOnFreeBorder,
                               in smIdType SecondNodeIDOnFreeBorder,
                               in smIdType LastNodeIDOnFreeBorder,
                               in smIdType FirstNodeIDOnSide,
                               in smIdType LastNodeIDOnSide,
                               in boolean  CreatePolygons,
                               in boolean  CreatePolyedrs) 
      raises (SALOME::SALOME_Exception);
 
    Sew_Error SewSideElements (in smIdType_array IDsOfSide1Elements,
                               in smIdType_array IDsOfSide2Elements,
                               in smIdType       NodeID1OfSide1ToMerge,
                               in smIdType       NodeID1OfSide2ToMerge,
                               in smIdType       NodeID2OfSide1ToMerge,
                               in smIdType       NodeID2OfSide2ToMerge) 
      raises (SALOME::SALOME_Exception);
 
    boolean ChangeElemNodes(in smIdType id, in smIdType_array newIDs) 
      raises (SALOME::SALOME_Exception);
 
    SMESH_Group DoubleElements( in SMESH_IDSource theElements, 
                                in string         theGroupName )
      raises (SALOME::SALOME_Exception);
 
    boolean DoubleNodes( in smIdType_array theNodes, in smIdType_array theModifiedElems ) 
      raises (SALOME::SALOME_Exception);
 
    boolean DoubleNode( in smIdType theNodeId, in smIdType_array theModifiedElems ) 
      raises (SALOME::SALOME_Exception);
 
    boolean DoubleNodeGroup( in SMESH_GroupBase theNodes,
                             in SMESH_GroupBase theModifiedElems ) 
      raises (SALOME::SALOME_Exception);
    SMESH_Group DoubleNodeGroupNew( in SMESH_GroupBase theNodes,
                                    in SMESH_GroupBase theModifiedElems ) 
      raises (SALOME::SALOME_Exception);
 
    boolean DoubleNodeGroups( in ListOfGroups theNodes,
                              in ListOfGroups theModifiedElems ) 
      raises (SALOME::SALOME_Exception);
    SMESH_Group DoubleNodeGroupsNew( in ListOfGroups theNodes,
                         in ListOfGroups theModifiedElems ) 
      raises (SALOME::SALOME_Exception);
 
    boolean DoubleNodeElem( in smIdType_array theElems,
                            in smIdType_array theNodesNot,
                            in smIdType_array theAffectedElems ) 
      raises (SALOME::SALOME_Exception);
 
    boolean DoubleNodeElemInRegion( in smIdType_array    theElems,
                                    in smIdType_array    theNodesNot,
                                    in GEOM::GEOM_Object theShape ) 
      raises (SALOME::SALOME_Exception);
 
    boolean DoubleNodeElemGroup( in SMESH_GroupBase theElems,
                                 in SMESH_GroupBase theNodesNot,
                                 in SMESH_GroupBase theAffectedElems ) 
      raises (SALOME::SALOME_Exception);
    SMESH_Group DoubleNodeElemGroupNew( in SMESH_GroupBase theElems,
                                        in SMESH_GroupBase theNodesNot,
                                        in SMESH_GroupBase theAffectedElems ) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups DoubleNodeElemGroup2New( in SMESH_GroupBase theElems,
                                          in SMESH_GroupBase theNodesNot,
                                          in SMESH_GroupBase theAffectedElems,
                                          in boolean         theElemGroupNeeded,
                                          in boolean         theNodeGroupNeeded) 
      raises (SALOME::SALOME_Exception);
 
    boolean DoubleNodeElemGroupInRegion( in SMESH_GroupBase theElems,
                                         in SMESH_GroupBase theNodesNot,
                                         in GEOM::GEOM_Object theShape ) 
      raises (SALOME::SALOME_Exception);
 
    boolean DoubleNodeElemGroups( in ListOfGroups theElems,
                                  in ListOfGroups theNodesNot,
                                  in ListOfGroups theAffectedElems ) 
      raises (SALOME::SALOME_Exception);
    SMESH_Group DoubleNodeElemGroupsNew( in ListOfGroups theElems,
                                         in ListOfGroups theNodesNot,
                                         in ListOfGroups theAffectedElems ) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups DoubleNodeElemGroups2New( in ListOfGroups theElems,
                                           in ListOfGroups theNodesNot,
                                           in ListOfGroups theAffectedElems,
                                           in boolean         theElemGroupNeeded,
                                           in boolean         theNodeGroupNeeded ) 
      raises (SALOME::SALOME_Exception);
 
    boolean DoubleNodeElemGroupsInRegion( in ListOfGroups theElems,
                                          in ListOfGroups theNodesNot,
                                          in GEOM::GEOM_Object theShape )
      raises (SALOME::SALOME_Exception);
 
    ListOfGroups AffectedElemGroupsInRegion( in ListOfGroups theElems,
                                             in ListOfGroups theNodesNot,
                                             in GEOM::GEOM_Object theShape ) 
      raises (SALOME::SALOME_Exception);
 
    boolean Make2DMeshFrom3D() raises (SALOME::SALOME_Exception);
 
    SMESH_Mesh MakeBoundaryMesh(in SMESH_IDSource elements,
                                in Bnd_Dimension  dimension,
                                in string         groupName,
                                in string         meshName,
                                in boolean        toCopyElements,
                                in boolean        toCopyExistingBondary,
                                out SMESH_Group   group) raises (SALOME::SALOME_Exception);
    long MakeBoundaryElements(in Bnd_Dimension   dimension,
                              in string          groupName,
                              in string          meshName,
                              in boolean         toCopyAll,
                              in boolean         toCreateAllElements,
                              in ListOfIDSources groups,
                              out SMESH_Mesh     mesh,
                              out SMESH_Group    group) raises (SALOME::SALOME_Exception);
 
    boolean DoubleNodesOnGroupBoundaries( in ListOfGroups theDomains,
                                          in boolean      createJointElems,
                                          in boolean      onAllBoundaries) 
      raises (SALOME::SALOME_Exception);
 
    boolean CreateFlatElementsOnFacesGroups( in ListOfGroups theGroupsOfFaces ) 
      raises (SALOME::SALOME_Exception); 
 
    void CreateHoleSkin(in double radius,
                        in GEOM::GEOM_Object theShape,
                        in string groupName,
                        in double_array theNodesCoords,
                        out array_of_long_array GroupsOfNodes)
      raises (SALOME::SALOME_Exception);
 
 
    void MakePolyLine(inout ListOfPolySegments segments,
                      in    string             groupName)
      raises (SALOME::SALOME_Exception);
 
    ListOfEdges MakeSlot( in SMESH_GroupBase segments,
                          in double          width )
      raises (SALOME::SALOME_Exception);
 
  };
};
 
#endif